;
; Front Matter
;

; Include relevant libraries
#Include "../lib/Prelude.ahk"
#Include "../lib/HoldRepeat.ahk"

; Make this a wrapper script
WrapperPath:="steam://rungameid/548430"
WrapperWindow:="Deep Rock Galactic  "
#Include "../lib/Wrapper.ahk"

; Initialize variables
FullAutoEnabled := [0,0,0,0,1]
EquipState := 1

ToggleFullAuto(Index) {
    global FullAutoEnabled
    FullAutoEnabled[Index] := !FullAutoEnabled[Index]
    EnabledDisabled := (FullAutoEnabled[Index] ? "enabled" : "disabled")
    if (Index == 5) {
        ToolTip "Distruptive macros " EnabledDisabled, A_ScreenWidth // 2, A_ScreenHeight // 2
    } else {
        ToolTip "Full Auto " EnabledDisabled " for " Index, A_ScreenWidth // 2, A_ScreenHeight // 2
    }
    SetTimer RemoveTooltip, -1000
}

RemoveTooltip() {
    ToolTip
}

;
; Hotkeys
;

;
; Full Auto
;

; Keep track of what is equipped
~*1:: global EquipState:=1
~*2:: global EquipState:=2
~*3:: global EquipState:=3
~*4:: global EquipState:=4

; FN toggles full auto for weapon N
*F1::ToggleFullAuto(1)
*F2::ToggleFullAuto(2)
*F3::ToggleFullAuto(3)
*F4::ToggleFullAuto(4)
*F5::ToggleFullAuto(5)

; Do full auto when caps lock is on for enabled weapons
#HotIf (GetKeyState("CapsLock","T") and FullAutoEnabled[EquipState])
*LButton::Repeat("LButton")

;
; Distruptive macros
;
#HotIf FullAutoEnabled[5]

; Hold f to rapidly deposit
*f::{
    While GetKeyState("f","P") {
        Send "{Blind}{e down}"
        Sleep 20
        Send "{Blind}{LCtrl down}"
        Sleep 20
        Send "{Blind}{LCtrl up}{e up}"
        Sleep 20
    }
}

;
; Non-disruptive macros
;
#HotIf

; Alt + E holds E
*!e UP::Hold("e",["e","w","a","s","d","Space","LButton","RButton"])

; Press shift to sprint, only toggles on
*LShift::{
    Send "{Blind}{LShift up}{LShift down}"
    KeyWait("LShift")
}
*LShift UP::Hold("LShift",,"w")

; Grenade animation canceling
*MButton::Send "{Blind}{LCtrl down}{MButton down}"
*MButton UP::Send "{Blind}{LCtrl up}{MButton up}"