;
; Front Matter
;

; Include relevant libraries
#Include "../lib/Prelude.ahk"
#Include "../lib/HoldRepeat.ahk"

; Initialize variables
FullAutoDefault := [0,0,0,0,1]
EquipState := 1

; Make this a wrapper script
WrapperPath:="steam://rungameid/548430"
WrapperWindow:="Deep Rock Galactic  "
#Include "../lib/Wrapper.ahk"

ToggleFullAuto(Index) {
    global FullAutoDefault
    FullAutoDefault[Index] := !FullAutoDefault[Index]
    if (Index == 5) {
        ToolTip "Distruptive macros " (FullAutoDefault[Index] ? "enabled" : "disabled"), A_ScreenWidth // 2, A_ScreenHeight // 2
    } else {
        ToolTip "Default for " Index " set to " (FullAutoDefault[Index] ? "fully automatic" : "semi automatic"), A_ScreenWidth // 2, A_ScreenHeight // 2
    }
    SetTimer RemoveTooltip, -1000
}

RemoveTooltip() {
    ToolTip
}

;
; Hotkeys
;

;
; Full Auto
;

; Keep track of what is equipped
~*1:: global EquipState:=1
~*2:: global EquipState:=2
~*3:: global EquipState:=3
~*4:: global EquipState:=4

; FN toggles full auto by default for weapon N
*F1::ToggleFullAuto(1)
*F2::ToggleFullAuto(2)
*F3::ToggleFullAuto(3)
*F4::ToggleFullAuto(4)
*F5::ToggleFullAuto(5)

; If default is semi auto, Shift + LMB does full auto
#HotIf !FullAutoDefault[EquipState]
*+LButton::Repeat("LButton")

; If default is full auto, just LMB by itself does full auto
#HotIf FullAutoDefault[EquipState]
*LButton::Repeat("LButton")
~*+LButton::

;
; Non-disruptive macros
;
#HotIf

; Alt + E holds E
*!e UP::Hold("e",["e","w","a","s","d","Space","LButton","RButton"])

; Grenade animation canceling
*MButton::Send "{Blind}{RCtrl down}{MButton down}"
*MButton UP::Send "{Blind}{RCtrl up}{MButton up}"

;
; Distruptive macros
;
#HotIf FullAutoDefault[5]

; Hold f to rapidly deposit
*f::{
    While GetKeyState("f","P") {
        Send "{Blind}{e down}"
        Sleep 20
        Send "{Blind}{RCtrl down}"
        Sleep 20
        Send "{Blind}{RCtrl up}{e up}"
        Sleep 20
    }
}